pkgs/arcanist/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

{
  lib,
  stdenv,
  fetchFromGitHub,
  makeWrapper,
  php82,
  python3,
  git,
  diffutils,
}:
stdenv.mkDerivation rec {
  pname = "arcanist";
  version = "2025.51";

  src = fetchFromGitHub {
    owner = "phorgeit";
    repo = "arcanist";
    rev = version;
    hash = "sha256-muqNbQBLDOLhzVSF7vTckhb6ouIcj6tHR20CFsgv9bQ=";
  };

  nativeBuildInputs = [makeWrapper];

  dontBuild = true;

  buildInputs = [
    php82
    python3
    git
    diffutils
  ];

  configurePhase = ''
    runHook preConfigure

    patchShebangs .

    runHook postConfigure
  '';

  installPhase = ''
    runHook preInstall
    mkdir -p $out/share/php/arcanist $out/bin

    cp --target-directory=$out/share/php/arcanist --recursive \
      bin externals resources scripts src support

    makeWrapper $out/share/php/arcanist/bin/arc $out/bin/arc \
      --inherit-argv0 \
      --chdir $out/share/php/arcanist \
      --prefix PATH : ${lib.makeBinPath buildInputs}

    makeWrapper $out/share/php/arcanist/bin/phage $out/bin/phage \
      --inherit-argv0 \
      --chdir $out/share/php/arcanist \
      --prefix PATH : ${lib.makeBinPath buildInputs}

    runHook postInstall
  '';
}