flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108

{
  description = "NixOS configuration";

  inputs = {
    # nixpkgs
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    # home manager
    home-manager.url = "github:nix-community/home-manager/master";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";
    # hyprland
    hyprland.url = "github:hyprwm/Hyprland";
    hyprland.inputs.nixpkgs.follows = "nixpkgs";
    # hyprland plugins
    hyprland-plugins.url = "github:hyprwm/hyprland-plugins";
    hyprland-plugins.inputs.hyprland.follows = "hyprland";
    # hyprland hy3
    hy3.url = "github:outfoxxed/hy3";
    hy3.inputs.hyprland.follows = "hyprland";
    # sops
    sops-nix.url = "github:Mic92/sops-nix";
    sops-nix.inputs.nixpkgs.follows = "nixpkgs";
    # astal
    astal.url = "github:aylur/astal";
    astal.inputs.nixpkgs.follows = "nixpkgs";
    # talc
    talc.url = "git+https://g.trimill.xyz/talc";
    talc.inputs.nixpkgs.follows = "nixpkgs";
    # apple-fonts
    apple-fonts.url = "github:Lyndeno/apple-fonts.nix";
    apple-fonts.inputs.nixpkgs.follows = "nixpkgs";
    # nixos-wsl
    nixos-wsl.url = "github:nix-community/nixos-wsl";
    nixos-wsl.inputs.nixpkgs.follows = "nixpkgs";
    # rose-pine-hyprcursor
    rose-pine-hyprcursor.url = "github:ndom91/rose-pine-hyprcursor";
    rose-pine-hyprcursor.inputs.nixpkgs.follows = "nixpkgs";
    rose-pine-hyprcursor.inputs.hyprlang.follows = "hyprland/hyprlang";
  };

  outputs = {
    self,
    nixpkgs,
    ...
  } @ inputs: let
    options = import ./options.nix;
    systems = ["x86_64-linux"];
    perSystem = func:
      builtins.listToAttrs (map (
          system: let
            pkgs = nixpkgs.legacyPackages.${system};
          in {
            name = system;
            value = func pkgs system;
          }
        )
        systems);
    buildSystem = file: system:
      inputs.nixpkgs.lib.nixosSystem {
        inherit system;
        specialArgs = {inherit self inputs system;};
        modules = [
          options
          ./home
          ./modules
          ./system
          file
        ];
      };
  in rec {
    nixosConfigurations = {
      shinji = buildSystem ./hosts/shinji "x86_64-linux";
      kaworu = buildSystem ./hosts/kaworu "x86_64-linux";
      thinkpad = buildSystem ./hosts/thinkpad "x86_64-linux";
      wsl = buildSystem ./hosts/wsl "x86_64-linux";
    };

    homeConfigurations = {
      shinji = nixosConfigurations.shinji.config.home-manager.users.${options.user}.home;
      kaworu = nixosConfigurations.kaworu.config.home-manager.users.${options.user}.home;
      thinkpad = nixosConfigurations.thinkpad.config.home-manager.users.${options.user}.home;
    };

    lib = import ./lib {
      inherit inputs options;
      inherit (nixpkgs) lib;
    };

    packages = perSystem (
      pkgs: system:
        import ./pkgs {
          inherit pkgs inputs system options;
          inherit (nixpkgs) lib;
        }
    );

    legacyPackages = packages;

    formatter = perSystem (
      pkgs: system:
        pkgs.alejandra
    );

    devShell = perSystem (
      pkgs: system:
        pkgs.mkShell {}
    );
  };
}