1 files changed, 40 insertions, 0 deletions
diff --git a/home/qt/default.nix b/home/qt/default.nix
new file mode 100644
index 0000000..3071bf4
--- /dev/null
+++ b/home/qt/default.nix
@@ -0,0 +1,40 @@
+{
+  lib,
+  config,
+  ...
+}: let
+  mkQtctConf = font:
+    lib.generators.toINI {}
+    {
+      Appearance = {
+        custom_palette = false;
+        icon_theme = config.gtk.iconTheme.name;
+        standard_dialogs = "xdgdesktopportal";
+        style = "kvantum";
+      };
+      Fonts = {
+        fixed = font;
+        general = font;
+      };
+    };
+in {
+  qt = {
+    enable = true;
+    platformTheme.name = "qtct";
+    style.name = "kvantum";
+  };
+
+  xdg.configFile = let
+    font = "${config.theme.font.regular},10";
+  in {
+    # load in Kvantum theme
+    "Kvantum/kvantum.kvconfig".text = lib.generators.toINI {} {
+      General.theme = "theme";
+    };
+    "Kvantum/theme/theme.svg".text = import ./svg.nix {inherit config;};
+    "Kvantum/theme/theme.kvconfig".text = import ./kvconfig.nix {inherit config;};
+
+    "qt5ct/qt5ct.conf".text = mkQtctConf ''"${font},-1,5,50,0,0,0,0,0"'';
+    "qt6ct/qt6ct.conf".text = mkQtctConf ''"${font},-1,5,400,0,0,0,0,0,0,0,0,0,0,1,Regular"'';
+  };
+}