1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
|
extern idt_exception_handler
global isr_stub_table
extern idt_pic_timer
extern idt_pic_keyboard
extern idt_pic_mouse
extern idt_pic_eoi
%macro PUSHALL 0
push rax
push rbx
push rcx
push rdx
push rbp
push rdi
push rsi
push r8
push r9
push r10
push r11
push r12
push r13
push r14
push r15
%endmacro
%macro POPALL 0
pop r15
pop r14
pop r13
pop r12
pop r11
pop r10
pop r9
pop r8
pop rsi
pop rdi
pop rbp
pop rdx
pop rcx
pop rbx
pop rax
%endmacro
; call the exception handler with the interrupt number
; args: interrupt number
%macro ISRException 1
align 8
isr_stub_%+%1:
PUSHALL
cld
mov rdi, %1 ; exception number
mov rsi, 0 ; placeholder error code
mov rdx, [rsp + 15 * 8] ; instruction pointer
mov rcx, rbp ; base pointer for stack trace
call idt_exception_handler
POPALL
iretq
%endmacro
; call the exception handler with the interrupt number
; these exceptions also put an error code on the stack
; args: interrupt number
%macro ISRExceptionCode 1
align 8
isr_stub_%+%1:
PUSHALL
cld
mov rdi, %1 ; exception number
mov rsi, [rsp + 15 * 8] ; error code
mov rdx, [rsp + 16 * 8] ; instruction pointer
mov rcx, rbp ; base pointer for stack trace
call idt_exception_handler
POPALL
sub rsp, 8 ; discard error code
iretq
%endmacro
%macro PICGeneric 1
isr_stub_%+%1:
PUSHALL
cld
mov rdi, %1
call idt_pic_eoi
POPALL
iretq
%endmacro
%macro PICTimer 1
isr_stub_%+%1:
PUSHALL
cld
call idt_pic_timer
mov rdi, %1
call idt_pic_eoi
POPALL
iretq
%endmacro
%macro PICKeyboard 1
isr_stub_%+%1:
PUSHALL
cld
call idt_pic_keyboard
mov rdi, %1
call idt_pic_eoi
POPALL
iretq
%endmacro
%macro PICMouse 1
isr_stub_%+%1:
PUSHALL
cld
call idt_pic_mouse
mov rdi, %1
call idt_pic_eoi
POPALL
iretq
%endmacro
; do nothing
; args: interrupt number
%macro ISRIgnore 1
align 8
isr_stub_%+%1:
iretq
%endmacro
; isr stubs
section .text
bits 64
ISRException 0
ISRException 1
ISRException 2
ISRException 3
ISRException 4
ISRException 5
ISRException 6
ISRException 7
ISRExceptionCode 8
ISRException 9
ISRExceptionCode 10
ISRExceptionCode 11
ISRExceptionCode 12
ISRExceptionCode 13
ISRExceptionCode 14
ISRException 15
ISRException 16
ISRExceptionCode 17
ISRException 18
ISRException 19
ISRException 20
ISRExceptionCode 21
ISRException 22
ISRException 23
ISRException 24
ISRException 25
ISRException 26
ISRException 27
ISRException 28
ISRExceptionCode 29
ISRExceptionCode 30
ISRException 31
PICTimer 32 ; 0
PICKeyboard 33 ; 1
PICGeneric 34 ; 2
PICGeneric 35 ; 3
PICGeneric 36 ; 4
PICGeneric 37 ; 5
PICGeneric 38 ; 6
PICGeneric 39 ; 7
PICGeneric 40 ; 8
PICGeneric 41 ; 9
PICGeneric 42 ; 10
PICGeneric 43 ; 11
PICMouse 44 ; 12
PICGeneric 45 ; 13
PICGeneric 46 ; 14
PICGeneric 47 ; 15
; ignore other interrupts
%assign i 48
%rep 256 - i
ISRIgnore i
%assign i i+1
%endrep
; isr stub table
section .rodata
bits 64
align 16
isr_stub_table:
%assign i 0
%rep 256
dq isr_stub_%+i
%assign i i+1
%endrep
|
