flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

{
  description = "systems programming x86";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs?ref=nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = {
    nixpkgs,
    flake-utils,
    ...
  }: let
    supportedSystems = let
      inherit (flake-utils.lib) system;
    in [
      system.aarch64-linux
      system.aarch64-darwin
      system.x86_64-linux
    ];
  in
    flake-utils.lib.eachSystem supportedSystems (system: let
      pkgs = import nixpkgs {inherit system;};
    in {
      devShell =
        (pkgs.mkShell.override { stdenv = pkgs.gcc14Stdenv; })
        {
          packages = with pkgs; [
            gnumake
            gdb
            qemu
            grub2_light
            xorriso
            gnu-efi
            (pkgs.writeShellScriptBin "qemu-system-x86_64-uefi" ''
              qemu-system-x86_64 \
                -smbios type=0,uefi=on \
                -bios ${pkgs.OVMF.fd}/FV/OVMF.fd \
                "$@"
            '')
            (pkgs.writeShellScriptBin "grub-mkrescue-uefi" ''
              ${pkgs.grub2_efi}/bin/grub-mkrescue "$@"
            '')
          ];
        };

      formatter = pkgs.alejandra;
    });
}