utils/Searcher.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

import Quickshell

import "scripts/fzf.js" as Fzf
import "scripts/fuzzysort.js" as Fuzzy
import QtQuick

Singleton {
    required property list<QtObject> list
    property string key: "name"
    property bool useFuzzy: false
    property var extraOpts: ({})

    readonly property var fzf: useFuzzy ? [] : new Fzf.Finder(list, Object.assign({
        selector: e => e[key]
    }, extraOpts))
    readonly property list<var> fuzzyPrepped: useFuzzy ? list.map(e => ({
                [key]: e[key],
                _item: e
            })) : []

    function transformSearch(search: string): string {
        return search;
    }

    function query(search: string): list<var> {
        search = transformSearch(search);
        if (!search)
            return [...list];

        if (useFuzzy)
            return Fuzzy.go(search, fuzzyPrepped, Object.assign({
                all: true,
                key
            }, extraOpts)).map(r => r.obj._item);

        return fzf.find(search).sort((a, b) => {
            if (a.score === b.score)
                return a.item[key].trim().length - b.item[key].trim().length;
            return b.score - a.score;
        }).map(r => r.item);
    }
}