services/Apps.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

pragma Singleton

import "root:/utils/scripts/fuzzysort.js" as Fuzzy
import "root:/widgets"
import "root:/config"
import Quickshell
import Quickshell.Io
import QtQuick

Singleton {
    id: root

    readonly property list<DesktopEntry> list: DesktopEntries.applications.values.filter(a => !a.noDisplay).sort((a, b) => a.name.localeCompare(b.name))
    readonly property list<var> preppedNames: list.map(a => ({
                name: Fuzzy.prepare(a.name),
                entry: a
            }))

    function fuzzyQuery(search: string): var { // Idk why list<DesktopEntry> doesn't work
        return Fuzzy.go(search, preppedNames, {
            all: true,
            key: "name"
        }).map(r => r.obj.entry);
    }

    function launch(entry: DesktopEntry): void {
        launchProc.createObject(root, {
            entry
        });
    }

    Component {
        id: launchProc

        Process {
            required property DesktopEntry entry

            running: true
            command: ["app2unit", "--", `${entry.id}.desktop`]
        }
    }
}