From 2dbec4489eabc68c071c8bdf5451af2284e20485 Mon Sep 17 00:00:00 2001
From: 2 * r + 2 * t <61896496+soramanew@users.noreply.github.com>
Date: Tue, 17 Jun 2025 15:55:26 +1000
Subject: feat: impl scheme launcher action

---
 modules/launcher/Schemes.qml | 67 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 modules/launcher/Schemes.qml

(limited to 'modules/launcher/Schemes.qml')

diff --git a/modules/launcher/Schemes.qml b/modules/launcher/Schemes.qml
new file mode 100644
index 0000000..3bdc90a
--- /dev/null
+++ b/modules/launcher/Schemes.qml
@@ -0,0 +1,67 @@
+pragma Singleton
+
+import "root:/utils/scripts/fuzzysort.js" as Fuzzy
+import "root:/config"
+import Quickshell
+import Quickshell.Io
+import QtQuick
+
+Singleton {
+    id: root
+
+    readonly property list<var> preppedActions: schemes.instances.map(s => ({
+                name: Fuzzy.prepare(s.name),
+                flavour: Fuzzy.prepare(s.flavour),
+                scheme: s
+            }))
+
+    function fuzzyQuery(search: string): var {
+        return Fuzzy.go(search.slice(`${Config.launcher.actionPrefix}scheme `.length), preppedActions, {
+            all: true,
+            keys: ["name", "flavour"],
+            scoreFn: r => r[0].score > 0 ? r[0].score * 0.9 + r[1].score * 0.1 : 0
+        }).map(r => r.obj.scheme);
+    }
+
+    Variants {
+        id: schemes
+
+        Scheme {}
+    }
+
+    Process {
+        id: getSchemes
+
+        running: true
+        command: ["caelestia", "scheme", "list"]
+        stdout: StdioCollector {
+            onStreamFinished: {
+                const schemeData = JSON.parse(text);
+                const list = Object.entries(schemeData).map(([name, f]) => Object.entries(f).map(([flavour, colours]) => ({
+                                name,
+                                flavour,
+                                colours
+                            })));
+
+                const flat = [];
+                for (const s of list)
+                    for (const f of s)
+                        flat.push(f);
+
+                schemes.model = flat;
+            }
+        }
+    }
+
+    component Scheme: QtObject {
+        required property var modelData
+        readonly property string name: modelData.name
+        readonly property string flavour: modelData.flavour
+        readonly property var colours: modelData.colours
+
+        function onClicked(list: AppList): void {
+            Quickshell.execDetached(["caelestia", "scheme", "set", "-n", name, "-f", flavour]);
+            list.visibilities.launcher = false;
+        }
+    }
+}
-- 
cgit v1.2.3-freya